Ticket #541: conv2ooo.bat

@echo off
:: ----------------------------------------------------------------------
:: Sub-routines?
if "%~1"==":DoConv" (
  shift
  goto :DoConv
)

echo ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
echo ³ Conv2ooo                                                                    ³
echo ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄŽ
echo ³ Batch Conversion between MSOffice and OpenOffice.org (OOo) file formats     ³
echo ³ Jay Jones, 23-Jul-2006                                                      ³
echo ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

:: ----------------------------------------------------------------------
:: History
:: ----------------------------------------------------------------------
::   Date       | Author     | Description
:: -------------|------------|-------------------------------------------
::  23-Jul-2006 | Jay Jones  | BugFix - Added %~1 Fix to prevent long 
::              |            | filenames with " - " from breaking script
:: -------------|------------|-------------------------------------------
::  18-Jul-2006 | Jay Jones  | Created.
::              |            | Provides Batch bulk conversion of Office
::              |            | files using OpenOffice
:: -------------|------------|-------------------------------------------
::  18-Jul-2006 | Jay Jones  | Added File support to process input from file
::              |            | See OOoforum for details of XSLT filter
::              |            | http://www.oooforum.org/forum/viewtopic.phtml?t=3772
:: ----------------------------------------------------------------------

:: ----------------------------------------------------------------------
:: Set default values
set Inst=%0
set OooExe="%ProgramFiles%\OpenOffice.org 2.0\program\soffice.bin"
set OooRoot=///Standard.MyConversions
set Ooomacro=SaveAsOOOFlat
set Options=


:: ----------------------------------------------------------------------
:: Parse Command line
:: %1 Macro
:: [-File]
:: %2 Filename
if "%~1"=="" goto ShowHelp
if "%~1"=="-OOO" (
  shift
  set Ooomacro=SaveAsOOO
)
if "%~1"=="-OOOflat" (
  shift
  set Ooomacro=SaveAsOOOFlat
)

if "%~1"=="-File" (
  shift
  set Options=/F "delims=;"
)


:: ----------------------------------------------------------------------
:: Expand Command Line & Call DoConversion Sub-routine
echo Expanding command line "%~1" ...
for %Options% %%I IN ("%~1") DO call %Inst% :DoConv %Ooomacro% "%%~fI"

goto CleanUp

:: ----------------------------------------------------------------------
:: SUB-ROUTINES
:: ----------------------------------------------------------------------

:: ----------------------------------------------------------------------
:: DoConv Sub-routine
:: ----------------------------------------------------------------------
:DoConv
echo Converting %~2 to %1 ...
%OooExe% macro:%OooRoot%.%1("%~2")
goto End

:: ----------------------------------------------------------------------
:ShowHelp
:: ----------------------------------------------------------------------
echo.
echo Syntax:
echo   conv2ooo [-oooflat,-ooo] [-File] FileMatch
echo.
echo     -oooflat  Converts files to Flat OpenDocument XML format (*.oft)
echo     -ooo      Converts to OpenOffice OpenDocument format     (*.odt)
echo     -File     Reads list of files to convert from text file
echo     FileMatch Expression to select file (Supports Wildcards)
echo.
pause
goto CleanUp

:: ----------------------------------------------------------------------
:CleanUp
:: ----------------------------------------------------------------------
set Inst=
set OooExe=
set OooRoot=
set OooMacro=
set File=

goto End

:End